home *** CD-ROM | disk | FTP | other *** search
/ ADA Programming Guide / ADA Programming Guide.iso / ada_gnu / adainc / s-valllu.adb < prev    next >
Text File  |  1996-01-30  |  8KB  |  249 lines
  1. ------------------------------------------------------------------------------
  2. --                                                                          --
  3. --                         GNAT COMPILER COMPONENTS                         --
  4. --                                                                          --
  5. --                       S Y S T E M . V A L _ L L U                        --
  6. --                                                                          --
  7. --                                 S p e c                                  --
  8. --                                                                          --
  9. --                            $Revision: 1.6 $                              --
  10. --                                                                          --
  11. --           Copyright (c) 1992,1993,1994 NYU, All Rights Reserved          --
  12. --                                                                          --
  13. -- The GNAT library is free software; you can redistribute it and/or modify --
  14. -- it under terms of the GNU Library General Public License as published by --
  15. -- the Free Software  Foundation; either version 2, or (at your option) any --
  16. -- later version.  The GNAT library is distributed in the hope that it will --
  17. -- be useful, but WITHOUT ANY WARRANTY;  without even  the implied warranty --
  18. -- of MERCHANTABILITY  or  FITNESS FOR  A PARTICULAR PURPOSE.  See the  GNU --
  19. -- Library  General  Public  License for  more  details.  You  should  have --
  20. -- received  a copy of the GNU  Library  General Public License  along with --
  21. -- the GNAT library;  see the file  COPYING.LIB.  If not, write to the Free --
  22. -- Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.        --
  23. --                                                                          --
  24. ------------------------------------------------------------------------------
  25.  
  26. with System.Unsigned_Types; use System.Unsigned_Types;
  27. with System.Val_Util;       use System.Val_Util;
  28.  
  29. package body System.Val_LLU is
  30.  
  31.    -----------------------------
  32.    -- Scan_Long_Long_Unsigned --
  33.    -----------------------------
  34.  
  35.    function Scan_Long_Long_Unsigned
  36.      (Str  : String;
  37.       Ptr  : access Positive'Base;
  38.       Max  : Positive'Base)
  39.       return Long_Long_Unsigned
  40.    is
  41.       P : Positive'Base;
  42.       --  Local copy of the pointer
  43.  
  44.       Uval : Long_Long_Unsigned;
  45.       --  Accumulated unsigned integer result (in the loop to scan out based
  46.       --  numbers, this is the value of the base, scanned on entry)
  47.  
  48.       Bval : Long_Long_Unsigned;
  49.       --  Value of based number accumulated
  50.  
  51.       New_Val : Long_Long_Unsigned;
  52.       --  Used in checking overflow during accumulation of result
  53.  
  54.       Expon : Integer;
  55.       --  Exponent value
  56.  
  57.       Minus : Boolean := False;
  58.       --  Set to True if minus sign is present, otherwise to False. Note that
  59.       --  a minus sign is permissible for the singular case of -0, and in any
  60.       --  case the pointer is left pointing past a negative integer literal.
  61.  
  62.       Overflow : Boolean := False;
  63.       --  Set True if overflow is detected at any point
  64.  
  65.       Start : Positive;
  66.       --  Save location of first non-blank character, not used for this case
  67.  
  68.       Base_Char : Character;
  69.       --  Base character (# or :) in based case
  70.  
  71.       Base : Long_Long_Unsigned := 10;
  72.       --  Base value (reset in based case)
  73.  
  74.       Digit : Long_Long_Unsigned;
  75.       --  Digit value (0..15) in based case
  76.  
  77.    begin
  78.       Scan_Sign (Str, Ptr, Max, Minus, Start);
  79.  
  80.       if Str (Ptr.all) not in '0' .. '9' then
  81.          Ptr.all := Start;
  82.          raise Constraint_Error;
  83.       end if;
  84.  
  85.       P := Ptr.all;
  86.       Uval := Character'Pos (Str (P)) - Character'Pos ('0');
  87.  
  88.       --  Loop to scan out digits of what is either the number or the base
  89.  
  90.       loop
  91.          P := P + 1;
  92.          exit when P > Max;
  93.  
  94.          --  Non-digit encountered
  95.  
  96.          if Str (P) not in '0' .. '9' then
  97.  
  98.             --  Only possibility is syntactically valid underline which we skip
  99.             --  otherwise exit from the loop, we are done with the scan.
  100.  
  101.             exit when Str (P) /= '_'
  102.               or else P >= Max
  103.               or else Str (P + 1) not in '0' .. '9';
  104.  
  105.          --  Accumulate result unless we have overflow. Overflow is detected
  106.          --  by the wrap around, which results in the a smaller value.
  107.  
  108.          else
  109.             New_Val :=
  110.               10 * Uval + Character'Pos (Str (P)) - Character'Pos ('0');
  111.  
  112.             if New_Val < Uval then
  113.                Overflow := True;
  114.             else
  115.                Uval := New_Val;
  116.             end if;
  117.          end if;
  118.       end loop;
  119.  
  120.       Ptr.all := P;
  121.  
  122.       --  Deal with based case
  123.  
  124.       if P < Max and then (Str (P) = ':' or else Str (P) = '#') then
  125.          Base_Char := Str (P);
  126.          P := P + 1;
  127.          Bval := 0;
  128.  
  129.          --  Check base value. Overflow is set True if we find a bad base, or
  130.          --  a digit that is out of range of the base. That way, we scan out
  131.          --  the numeral that is still syntactically correct, though illegal.
  132.  
  133.          if Uval not in 2 .. 16 then
  134.             Overflow := True;
  135.          end if;
  136.  
  137.          --  Loop to scan out based integer value
  138.  
  139.          loop
  140.             --  We require a digit at this stage. If we don't have one, then
  141.             --  it isn't a based number after all, so the number we scanned
  142.             --  out as the base (still in Uval) is the value we wnat.
  143.  
  144.             if Str (P) in '0' .. '9' then
  145.                Digit := Character'Pos (Str (P)) - Character'Pos ('0');
  146.  
  147.             elsif Str (P) in 'A' .. 'F' then
  148.                Digit := Character'Pos (Str (P)) - (Character'Pos ('A') - 10);
  149.  
  150.             elsif Str (P) in 'a' .. 'f' then
  151.                Digit := Character'Pos (Str (P)) - (Character'Pos ('a') - 10);
  152.             else
  153.                exit;
  154.             end if;
  155.  
  156.             --  Here we accumulate the value, checking overflow (which
  157.             --  is detected by wrap around leaving the result smaller)
  158.  
  159.             if Digit >= Uval then
  160.                Overflow := True;
  161.             else
  162.                New_Val := Bval * Uval + Digit;
  163.  
  164.                if New_Val < Bval then
  165.                   Overflow := True;
  166.                else
  167.                   Bval := New_Val;
  168.                end if;
  169.             end if;
  170.  
  171.             --  If at end of string with no base char, not a based number
  172.  
  173.             P := P + 1;
  174.             exit when P > Max;
  175.  
  176.             --  If terminating base character, we are done with loop
  177.  
  178.             if Str (P) = Base_Char then
  179.                Ptr.all := P + 1;
  180.                Base := Uval;
  181.                Uval := Bval;
  182.                exit;
  183.  
  184.             --  Just ignore an underline. Note that we will end up requiring a
  185.             --  digit to follow the underline, thus rejecting double underline
  186.  
  187.             elsif Str (P) = '_' then
  188.                P := P + 1;
  189.                exit when P > Max;
  190.             end if;
  191.  
  192.          end loop;
  193.       end if;
  194.  
  195.       --  Come here with scanned unsigned value in Uval. The only remaining
  196.       --  required step is to deal with exponent if one is present.
  197.  
  198.       Expon := Scan_Exponent (Str, Ptr, Max);
  199.  
  200.       if Expon /= 0 and then Uval /= 0 then
  201.  
  202.          --  For non-zero value, scale by exponent value. No need to do this
  203.          --  efficiently, since use of exponent in integer literals is rare,
  204.          --  and in any case the exponent cannot be very large.
  205.  
  206.          loop
  207.             New_Val := Uval * Base;
  208.  
  209.             if New_Val < Uval then
  210.                Overflow := True;
  211.             else
  212.                Uval := New_Val;
  213.             end if;
  214.  
  215.             Expon := Expon - 1;
  216.             exit when Expon = 0;
  217.          end loop;
  218.       end if;
  219.  
  220.       --  Return result, dealing with sign and overflow
  221.  
  222.       if Overflow or else (Minus and then Uval /= 0) then
  223.          raise Constraint_Error;
  224.       else
  225.          return Uval;
  226.       end if;
  227.  
  228.    end Scan_Long_Long_Unsigned;
  229.  
  230.    ------------------------------
  231.    -- Value_Long_Long_Unsigned --
  232.    ------------------------------
  233.  
  234.    function Value_Long_Long_Unsigned
  235.      (Str : String)
  236.      return Long_Long_Unsigned
  237.    is
  238.       V : Long_Long_Unsigned;
  239.       P : aliased Natural := Str'First;
  240.  
  241.    begin
  242.       V := Scan_Long_Long_Unsigned (Str, P'Access, Str'Last);
  243.       Scan_Trailing_Blanks (Str, P);
  244.       return V;
  245.  
  246.    end Value_Long_Long_Unsigned;
  247.  
  248. end System.Val_LLU;
  249.